Win10系統(tǒng)怎么為批處理文件自動(dòng)添加管理員權(quán)限

　　在win10系統(tǒng)中，我們可能經(jīng)常會(huì)需要運(yùn)行一些批處理文件，一般都要先手動(dòng)獲取管理員權(quán)限才可以，顯得有點(diǎn)麻煩，那么要其實(shí)可以為批處理文件自動(dòng)添加管理員權(quán)限，該怎么操作呢，本文就給大家講解一下Win10系統(tǒng)為批處理文件自動(dòng)添加管理員權(quán)限的具體步驟。

1、把如下代碼（分割線之間）復(fù)制到記事本中，并保存為 .bat 格式即可（文件名可自擬）；

————————— 分割線 —————————

@echo off

CLS

ECHO.

ECHO ================================

ECHO 獲取批處理文件管理員權(quán)限

ECHO ================================

:init

setlocal DisableDelayedExpansion

set "batchPath=%~0"

for %%k in (%0) do set batchName=%%~nk

set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"

setlocal EnableDelayedExpansion

:checkPrivileges

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges

if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)

ECHO.

ECHO ********************************

ECHO 請(qǐng)求 UAC 權(quán)限批準(zhǔn)……

ECHO ********************************

ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"

ECHO args = "ELEV " >> "%vbsGetPrivileges%"

ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"

ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"

ECHO Next >> "%vbsGetPrivileges%"

ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"

"%SystemRoot%\System32\WScript.exe" "%vbsGetPrivileges%" %*

exit /B

:gotPrivileges

setlocal & pushd .

cd /d %~dp0

if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::     以下為需要運(yùn)行的批處理文件代碼     ::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem 本行以下可修改為你需要的bat命令（從上面三行冒號(hào)開始到下面都可刪改）

ECHO 歡迎使用！

ECHO.

pause

————————— 分割線 —————————

以上代碼就是為你的bat內(nèi)容獲取管理員權(quán)限用的，加在你的代碼之前就可以用了。運(yùn)行效果如下：

▲圖片說明：如果你的系統(tǒng)開啟了UAC，那么就需要運(yùn)行后批準(zhǔn)一下（別嫌麻煩，最好開啟UAC，比較安全）

▲圖片說明：運(yùn)行示例（有小伙伴嫌CMD丑，所以你可以在屬性→顏色中調(diào)下背景透明度，再換個(gè)喜歡的壁紙……）

這個(gè)代碼也支持Win7/Win8.1系統(tǒng)，效果如下（Windows7為例）：

▲圖片說明：Win7的CMD還沒法設(shè)置透明背景

　　上述給大家介紹的就是Win10系統(tǒng)怎么為批處理文件自動(dòng)添加管理員權(quán)限的詳細(xì)操作步驟，有需要的用戶們可以按照上面的方法步驟來進(jìn)行操作吧。